Gitiles
Code Review Sign In
gerrit.omnirom.org / android_external_tigervnc / 3e0e2de120d9d10245e26143a52cd0f49d16f413 / . / common / jpeg / simd / jdcolmmx.asm
blob: 33d50634f745c24080a935865022ee30b3565c27 [file] [log] [blame]
Pierre Ossman3e0e2de2009-03-09 13:25:30 +0000[diff] [blame^]1;
2; jdcolmmx.asm - colorspace conversion (MMX)
3;
4; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
5;
6; Based on
7; x86 SIMD extension for IJG JPEG library
8; Copyright (C) 1999-2006, MIYASAKA Masaru.
9; For conditions of distribution and use, see copyright notice in jsimdext.inc
10;
11; This file should be assembled with NASM (Netwide Assembler),
12; can *not* be assembled with Microsoft's MASM or any compatible
13; assembler (including Borland's Turbo Assembler).
14; NASM is available from http://nasm.sourceforge.net/ or
15; http://sourceforge.net/project/showfiles.php?group_id=6208
16;
17; [TAB8]
18
19%include "simd/jsimdext.inc"
20%include "simd/jcolsamp.inc"
21
22; --------------------------------------------------------------------------
23
24%define SCALEBITS 16
25
26F_0_344 equ 22554 ; FIX(0.34414)
27F_0_714 equ 46802 ; FIX(0.71414)
28F_1_402 equ 91881 ; FIX(1.40200)
29F_1_772 equ 116130 ; FIX(1.77200)
30F_0_402 equ (F_1_402 - 65536) ; FIX(1.40200) - FIX(1)
31F_0_285 equ ( 65536 - F_0_714) ; FIX(1) - FIX(0.71414)
32F_0_228 equ (131072 - F_1_772) ; FIX(2) - FIX(1.77200)
33
34; --------------------------------------------------------------------------
35 SECTION SEG_CONST
36
37 alignz 16
38 global EXTN(jconst_ycc_rgb_convert_mmx)
39
40EXTN(jconst_ycc_rgb_convert_mmx):
41
42PW_F0402 times 4 dw F_0_402
43PW_MF0228 times 4 dw -F_0_228
44PW_MF0344_F0285 times 2 dw -F_0_344, F_0_285
45PW_ONE times 4 dw 1
46PD_ONEHALF times 2 dd 1 << (SCALEBITS-1)
47
48 alignz 16
49
50; --------------------------------------------------------------------------
51 SECTION SEG_TEXT
52 BITS 32
53;
54; Convert some rows of samples to the output colorspace.
55;
56; GLOBAL(void)
57; jsimd_ycc_rgb_convert_mmx (JDIMENSION out_width,
58; JSAMPIMAGE input_buf, JDIMENSION input_row,
59; JSAMPARRAY output_buf, int num_rows)
60;
61
62%define out_width(b) (b)+8 ; JDIMENSION out_width
63%define input_buf(b) (b)+12 ; JSAMPIMAGE input_buf
64%define input_row(b) (b)+16 ; JDIMENSION input_row
65%define output_buf(b) (b)+20 ; JSAMPARRAY output_buf
66%define num_rows(b) (b)+24 ; int num_rows
67
68%define original_ebp ebp+0
69%define wk(i) ebp-(WK_NUM-(i))*SIZEOF_MMWORD ; mmword wk[WK_NUM]
70%define WK_NUM 2
71%define gotptr wk(0)-SIZEOF_POINTER ; void * gotptr
72
73 align 16
74 global EXTN(jsimd_ycc_rgb_convert_mmx)
75
76EXTN(jsimd_ycc_rgb_convert_mmx):
77 push ebp
78 mov eax,esp ; eax = original ebp
79 sub esp, byte 4
80 and esp, byte (-SIZEOF_MMWORD) ; align to 64 bits
81 mov [esp],eax
82 mov ebp,esp ; ebp = aligned ebp
83 lea esp, [wk(0)]
84 pushpic eax ; make a room for GOT address
85 push ebx
86; push ecx ; need not be preserved
87; push edx ; need not be preserved
88 push esi
89 push edi
90
91 get_GOT ebx ; get GOT address
92 movpic POINTER [gotptr], ebx ; save GOT address
93
94 mov ecx, JDIMENSION [out_width(eax)] ; num_cols
95 test ecx,ecx
96 jz near .return
97
98 push ecx
99
100 mov edi, JSAMPIMAGE [input_buf(eax)]
101 mov ecx, JDIMENSION [input_row(eax)]
102 mov esi, JSAMPARRAY [edi+0*SIZEOF_JSAMPARRAY]
103 mov ebx, JSAMPARRAY [edi+1*SIZEOF_JSAMPARRAY]
104 mov edx, JSAMPARRAY [edi+2*SIZEOF_JSAMPARRAY]
105 lea esi, [esi+ecx*SIZEOF_JSAMPROW]
106 lea ebx, [ebx+ecx*SIZEOF_JSAMPROW]
107 lea edx, [edx+ecx*SIZEOF_JSAMPROW]
108
109 pop ecx
110
111 mov edi, JSAMPARRAY [output_buf(eax)]
112 mov eax, INT [num_rows(eax)]
113 test eax,eax
114 jle near .return
115 alignx 16,7
116.rowloop:
117 push eax
118 push edi
119 push edx
120 push ebx
121 push esi
122 push ecx ; col
123
124 mov esi, JSAMPROW [esi] ; inptr0
125 mov ebx, JSAMPROW [ebx] ; inptr1
126 mov edx, JSAMPROW [edx] ; inptr2
127 mov edi, JSAMPROW [edi] ; outptr
128 movpic eax, POINTER [gotptr] ; load GOT address (eax)
129 alignx 16,7
130.columnloop:
131
132 movq mm5, MMWORD [ebx] ; mm5=Cb(01234567)
133 movq mm1, MMWORD [edx] ; mm1=Cr(01234567)
134
135 pcmpeqw mm4,mm4
136 pcmpeqw mm7,mm7
137 psrlw mm4,BYTE_BIT
138 psllw mm7,7 ; mm7={0xFF80 0xFF80 0xFF80 0xFF80}
139 movq mm0,mm4 ; mm0=mm4={0xFF 0x00 0xFF 0x00 ..}
140
141 pand mm4,mm5 ; mm4=Cb(0246)=CbE
142 psrlw mm5,BYTE_BIT ; mm5=Cb(1357)=CbO
143 pand mm0,mm1 ; mm0=Cr(0246)=CrE
144 psrlw mm1,BYTE_BIT ; mm1=Cr(1357)=CrO
145
146 paddw mm4,mm7
147 paddw mm5,mm7
148 paddw mm0,mm7
149 paddw mm1,mm7
150
151 ; (Original)
152 ; R = Y + 1.40200 * Cr
153 ; G = Y - 0.34414 * Cb - 0.71414 * Cr
154 ; B = Y + 1.77200 * Cb
155 ;
156 ; (This implementation)
157 ; R = Y + 0.40200 * Cr + Cr
158 ; G = Y - 0.34414 * Cb + 0.28586 * Cr - Cr
159 ; B = Y - 0.22800 * Cb + Cb + Cb
160
161 movq mm2,mm4 ; mm2=CbE
162 movq mm3,mm5 ; mm3=CbO
163 paddw mm4,mm4 ; mm4=2*CbE
164 paddw mm5,mm5 ; mm5=2*CbO
165 movq mm6,mm0 ; mm6=CrE
166 movq mm7,mm1 ; mm7=CrO
167 paddw mm0,mm0 ; mm0=2*CrE
168 paddw mm1,mm1 ; mm1=2*CrO
169
170 pmulhw mm4,[GOTOFF(eax,PW_MF0228)] ; mm4=(2*CbE * -FIX(0.22800))
171 pmulhw mm5,[GOTOFF(eax,PW_MF0228)] ; mm5=(2*CbO * -FIX(0.22800))
172 pmulhw mm0,[GOTOFF(eax,PW_F0402)] ; mm0=(2*CrE * FIX(0.40200))
173 pmulhw mm1,[GOTOFF(eax,PW_F0402)] ; mm1=(2*CrO * FIX(0.40200))
174
175 paddw mm4,[GOTOFF(eax,PW_ONE)]
176 paddw mm5,[GOTOFF(eax,PW_ONE)]
177 psraw mm4,1 ; mm4=(CbE * -FIX(0.22800))
178 psraw mm5,1 ; mm5=(CbO * -FIX(0.22800))
179 paddw mm0,[GOTOFF(eax,PW_ONE)]
180 paddw mm1,[GOTOFF(eax,PW_ONE)]
181 psraw mm0,1 ; mm0=(CrE * FIX(0.40200))
182 psraw mm1,1 ; mm1=(CrO * FIX(0.40200))
183
184 paddw mm4,mm2
185 paddw mm5,mm3
186 paddw mm4,mm2 ; mm4=(CbE * FIX(1.77200))=(B-Y)E
187 paddw mm5,mm3 ; mm5=(CbO * FIX(1.77200))=(B-Y)O
188 paddw mm0,mm6 ; mm0=(CrE * FIX(1.40200))=(R-Y)E
189 paddw mm1,mm7 ; mm1=(CrO * FIX(1.40200))=(R-Y)O
190
191 movq MMWORD [wk(0)], mm4 ; wk(0)=(B-Y)E
192 movq MMWORD [wk(1)], mm5 ; wk(1)=(B-Y)O
193
194 movq mm4,mm2
195 movq mm5,mm3
196 punpcklwd mm2,mm6
197 punpckhwd mm4,mm6
198 pmaddwd mm2,[GOTOFF(eax,PW_MF0344_F0285)]
199 pmaddwd mm4,[GOTOFF(eax,PW_MF0344_F0285)]
200 punpcklwd mm3,mm7
201 punpckhwd mm5,mm7
202 pmaddwd mm3,[GOTOFF(eax,PW_MF0344_F0285)]
203 pmaddwd mm5,[GOTOFF(eax,PW_MF0344_F0285)]
204
205 paddd mm2,[GOTOFF(eax,PD_ONEHALF)]
206 paddd mm4,[GOTOFF(eax,PD_ONEHALF)]
207 psrad mm2,SCALEBITS
208 psrad mm4,SCALEBITS
209 paddd mm3,[GOTOFF(eax,PD_ONEHALF)]
210 paddd mm5,[GOTOFF(eax,PD_ONEHALF)]
211 psrad mm3,SCALEBITS
212 psrad mm5,SCALEBITS
213
214 packssdw mm2,mm4 ; mm2=CbE*-FIX(0.344)+CrE*FIX(0.285)
215 packssdw mm3,mm5 ; mm3=CbO*-FIX(0.344)+CrO*FIX(0.285)
216 psubw mm2,mm6 ; mm2=CbE*-FIX(0.344)+CrE*-FIX(0.714)=(G-Y)E
217 psubw mm3,mm7 ; mm3=CbO*-FIX(0.344)+CrO*-FIX(0.714)=(G-Y)O
218
219 movq mm5, MMWORD [esi] ; mm5=Y(01234567)
220
221 pcmpeqw mm4,mm4
222 psrlw mm4,BYTE_BIT ; mm4={0xFF 0x00 0xFF 0x00 ..}
223 pand mm4,mm5 ; mm4=Y(0246)=YE
224 psrlw mm5,BYTE_BIT ; mm5=Y(1357)=YO
225
226 paddw mm0,mm4 ; mm0=((R-Y)E+YE)=RE=(R0 R2 R4 R6)
227 paddw mm1,mm5 ; mm1=((R-Y)O+YO)=RO=(R1 R3 R5 R7)
228 packuswb mm0,mm0 ; mm0=(R0 R2 R4 R6 ** ** ** **)
229 packuswb mm1,mm1 ; mm1=(R1 R3 R5 R7 ** ** ** **)
230
231 paddw mm2,mm4 ; mm2=((G-Y)E+YE)=GE=(G0 G2 G4 G6)
232 paddw mm3,mm5 ; mm3=((G-Y)O+YO)=GO=(G1 G3 G5 G7)
233 packuswb mm2,mm2 ; mm2=(G0 G2 G4 G6 ** ** ** **)
234 packuswb mm3,mm3 ; mm3=(G1 G3 G5 G7 ** ** ** **)
235
236 paddw mm4, MMWORD [wk(0)] ; mm4=(YE+(B-Y)E)=BE=(B0 B2 B4 B6)
237 paddw mm5, MMWORD [wk(1)] ; mm5=(YO+(B-Y)O)=BO=(B1 B3 B5 B7)
238 packuswb mm4,mm4 ; mm4=(B0 B2 B4 B6 ** ** ** **)
239 packuswb mm5,mm5 ; mm5=(B1 B3 B5 B7 ** ** ** **)
240
241%if RGB_PIXELSIZE == 3 ; ---------------
242
243 ; mmA=(00 02 04 06 ** ** ** **), mmB=(01 03 05 07 ** ** ** **)
244 ; mmC=(10 12 14 16 ** ** ** **), mmD=(11 13 15 17 ** ** ** **)
245 ; mmE=(20 22 24 26 ** ** ** **), mmF=(21 23 25 27 ** ** ** **)
246 ; mmG=(** ** ** ** ** ** ** **), mmH=(** ** ** ** ** ** ** **)
247
248 punpcklbw mmA,mmC ; mmA=(00 10 02 12 04 14 06 16)
249 punpcklbw mmE,mmB ; mmE=(20 01 22 03 24 05 26 07)
250 punpcklbw mmD,mmF ; mmD=(11 21 13 23 15 25 17 27)
251
252 movq mmG,mmA
253 movq mmH,mmA
254 punpcklwd mmA,mmE ; mmA=(00 10 20 01 02 12 22 03)
255 punpckhwd mmG,mmE ; mmG=(04 14 24 05 06 16 26 07)
256
257 psrlq mmH,2*BYTE_BIT ; mmH=(02 12 04 14 06 16 -- --)
258 psrlq mmE,2*BYTE_BIT ; mmE=(22 03 24 05 26 07 -- --)
259
260 movq mmC,mmD
261 movq mmB,mmD
262 punpcklwd mmD,mmH ; mmD=(11 21 02 12 13 23 04 14)
263 punpckhwd mmC,mmH ; mmC=(15 25 06 16 17 27 -- --)
264
265 psrlq mmB,2*BYTE_BIT ; mmB=(13 23 15 25 17 27 -- --)
266
267 movq mmF,mmE
268 punpcklwd mmE,mmB ; mmE=(22 03 13 23 24 05 15 25)
269 punpckhwd mmF,mmB ; mmF=(26 07 17 27 -- -- -- --)
270
271 punpckldq mmA,mmD ; mmA=(00 10 20 01 11 21 02 12)
272 punpckldq mmE,mmG ; mmE=(22 03 13 23 04 14 24 05)
273 punpckldq mmC,mmF ; mmC=(15 25 06 16 26 07 17 27)
274
275 cmp ecx, byte SIZEOF_MMWORD
276 jb short .column_st16
277
278 movq MMWORD [edi+0*SIZEOF_MMWORD], mmA
279 movq MMWORD [edi+1*SIZEOF_MMWORD], mmE
280 movq MMWORD [edi+2*SIZEOF_MMWORD], mmC
281
282 sub ecx, byte SIZEOF_MMWORD
283 jz short .nextrow
284
285 add esi, byte SIZEOF_MMWORD ; inptr0
286 add ebx, byte SIZEOF_MMWORD ; inptr1
287 add edx, byte SIZEOF_MMWORD ; inptr2
288 add edi, byte RGB_PIXELSIZE*SIZEOF_MMWORD ; outptr
289 jmp near .columnloop
290 alignx 16,7
291
292.column_st16:
293 lea ecx, [ecx+ecx*2] ; imul ecx, RGB_PIXELSIZE
294 cmp ecx, byte 2*SIZEOF_MMWORD
295 jb short .column_st8
296 movq MMWORD [edi+0*SIZEOF_MMWORD], mmA
297 movq MMWORD [edi+1*SIZEOF_MMWORD], mmE
298 movq mmA,mmC
299 sub ecx, byte 2*SIZEOF_MMWORD
300 add edi, byte 2*SIZEOF_MMWORD
301 jmp short .column_st4
302.column_st8:
303 cmp ecx, byte SIZEOF_MMWORD
304 jb short .column_st4
305 movq MMWORD [edi+0*SIZEOF_MMWORD], mmA
306 movq mmA,mmE
307 sub ecx, byte SIZEOF_MMWORD
308 add edi, byte SIZEOF_MMWORD
309.column_st4:
310 movd eax,mmA
311 cmp ecx, byte SIZEOF_DWORD
312 jb short .column_st2
313 mov DWORD [edi+0*SIZEOF_DWORD], eax
314 psrlq mmA,DWORD_BIT
315 movd eax,mmA
316 sub ecx, byte SIZEOF_DWORD
317 add edi, byte SIZEOF_DWORD
318.column_st2:
319 cmp ecx, byte SIZEOF_WORD
320 jb short .column_st1
321 mov WORD [edi+0*SIZEOF_WORD], ax
322 shr eax,WORD_BIT
323 sub ecx, byte SIZEOF_WORD
324 add edi, byte SIZEOF_WORD
325.column_st1:
326 cmp ecx, byte SIZEOF_BYTE
327 jb short .nextrow
328 mov BYTE [edi+0*SIZEOF_BYTE], al
329
330%else ; RGB_PIXELSIZE == 4 ; -----------
331
332%ifdef RGBX_FILLER_0XFF
333 pcmpeqb mm6,mm6 ; mm6=(X0 X2 X4 X6 ** ** ** **)
334 pcmpeqb mm7,mm7 ; mm7=(X1 X3 X5 X7 ** ** ** **)
335%else
336 pxor mm6,mm6 ; mm6=(X0 X2 X4 X6 ** ** ** **)
337 pxor mm7,mm7 ; mm7=(X1 X3 X5 X7 ** ** ** **)
338%endif
339 ; mmA=(00 02 04 06 ** ** ** **), mmB=(01 03 05 07 ** ** ** **)
340 ; mmC=(10 12 14 16 ** ** ** **), mmD=(11 13 15 17 ** ** ** **)
341 ; mmE=(20 22 24 26 ** ** ** **), mmF=(21 23 25 27 ** ** ** **)
342 ; mmG=(30 32 34 36 ** ** ** **), mmH=(31 33 35 37 ** ** ** **)
343
344 punpcklbw mmA,mmC ; mmA=(00 10 02 12 04 14 06 16)
345 punpcklbw mmE,mmG ; mmE=(20 30 22 32 24 34 26 36)
346 punpcklbw mmB,mmD ; mmB=(01 11 03 13 05 15 07 17)
347 punpcklbw mmF,mmH ; mmF=(21 31 23 33 25 35 27 37)
348
349 movq mmC,mmA
350 punpcklwd mmA,mmE ; mmA=(00 10 20 30 02 12 22 32)
351 punpckhwd mmC,mmE ; mmC=(04 14 24 34 06 16 26 36)
352 movq mmG,mmB
353 punpcklwd mmB,mmF ; mmB=(01 11 21 31 03 13 23 33)
354 punpckhwd mmG,mmF ; mmG=(05 15 25 35 07 17 27 37)
355
356 movq mmD,mmA
357 punpckldq mmA,mmB ; mmA=(00 10 20 30 01 11 21 31)
358 punpckhdq mmD,mmB ; mmD=(02 12 22 32 03 13 23 33)
359 movq mmH,mmC
360 punpckldq mmC,mmG ; mmC=(04 14 24 34 05 15 25 35)
361 punpckhdq mmH,mmG ; mmH=(06 16 26 36 07 17 27 37)
362
363 cmp ecx, byte SIZEOF_MMWORD
364 jb short .column_st16
365
366 movq MMWORD [edi+0*SIZEOF_MMWORD], mmA
367 movq MMWORD [edi+1*SIZEOF_MMWORD], mmD
368 movq MMWORD [edi+2*SIZEOF_MMWORD], mmC
369 movq MMWORD [edi+3*SIZEOF_MMWORD], mmH
370
371 sub ecx, byte SIZEOF_MMWORD
372 jz short .nextrow
373
374 add esi, byte SIZEOF_MMWORD ; inptr0
375 add ebx, byte SIZEOF_MMWORD ; inptr1
376 add edx, byte SIZEOF_MMWORD ; inptr2
377 add edi, byte RGB_PIXELSIZE*SIZEOF_MMWORD ; outptr
378 jmp near .columnloop
379 alignx 16,7
380
381.column_st16:
382 cmp ecx, byte SIZEOF_MMWORD/2
383 jb short .column_st8
384 movq MMWORD [edi+0*SIZEOF_MMWORD], mmA
385 movq MMWORD [edi+1*SIZEOF_MMWORD], mmD
386 movq mmA,mmC
387 movq mmD,mmH
388 sub ecx, byte SIZEOF_MMWORD/2
389 add edi, byte 2*SIZEOF_MMWORD
390.column_st8:
391 cmp ecx, byte SIZEOF_MMWORD/4
392 jb short .column_st4
393 movq MMWORD [edi+0*SIZEOF_MMWORD], mmA
394 movq mmA,mmD
395 sub ecx, byte SIZEOF_MMWORD/4
396 add edi, byte 1*SIZEOF_MMWORD
397.column_st4:
398 cmp ecx, byte SIZEOF_MMWORD/8
399 jb short .nextrow
400 movd DWORD [edi+0*SIZEOF_DWORD], mmA
401
402%endif ; RGB_PIXELSIZE ; ---------------
403
404 alignx 16,7
405
406.nextrow:
407 pop ecx
408 pop esi
409 pop ebx
410 pop edx
411 pop edi
412 pop eax
413
414 add esi, byte SIZEOF_JSAMPROW
415 add ebx, byte SIZEOF_JSAMPROW
416 add edx, byte SIZEOF_JSAMPROW
417 add edi, byte SIZEOF_JSAMPROW ; output_buf
418 dec eax ; num_rows
419 jg near .rowloop
420
421 emms ; empty MMX state
422
423.return:
424 pop edi
425 pop esi
426; pop edx ; need not be preserved
427; pop ecx ; need not be preserved
428 pop ebx
429 mov esp,ebp ; esp <- aligned ebp
430 pop esp ; esp <- original ebp
431 pop ebp
432 ret
433