Gitiles
Code Review Sign In
gerrit.omnirom.org / android_external_tigervnc / 3e0e2de120d9d10245e26143a52cd0f49d16f413 / . / common / jpeg / simd / jccolmmx.asm
blob: 701a3271fe74124ae5b6956646658fd6a2bba39f [file] [log] [blame]
Pierre Ossman3e0e2de2009-03-09 13:25:30 +0000[diff] [blame^]1;
2; jccolmmx.asm - colorspace conversion (MMX)
3;
4; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
5;
6; Based on
7; x86 SIMD extension for IJG JPEG library
8; Copyright (C) 1999-2006, MIYASAKA Masaru.
9; For conditions of distribution and use, see copyright notice in jsimdext.inc
10;
11; This file should be assembled with NASM (Netwide Assembler),
12; can *not* be assembled with Microsoft's MASM or any compatible
13; assembler (including Borland's Turbo Assembler).
14; NASM is available from http://nasm.sourceforge.net/ or
15; http://sourceforge.net/project/showfiles.php?group_id=6208
16;
17; [TAB8]
18
19%include "simd/jsimdext.inc"
20%include "simd/jcolsamp.inc"
21
22; --------------------------------------------------------------------------
23
24%define SCALEBITS 16
25
26F_0_081 equ 5329 ; FIX(0.08131)
27F_0_114 equ 7471 ; FIX(0.11400)
28F_0_168 equ 11059 ; FIX(0.16874)
29F_0_250 equ 16384 ; FIX(0.25000)
30F_0_299 equ 19595 ; FIX(0.29900)
31F_0_331 equ 21709 ; FIX(0.33126)
32F_0_418 equ 27439 ; FIX(0.41869)
33F_0_587 equ 38470 ; FIX(0.58700)
34F_0_337 equ (F_0_587 - F_0_250) ; FIX(0.58700) - FIX(0.25000)
35
36; --------------------------------------------------------------------------
37 SECTION SEG_CONST
38
39 alignz 16
40 global EXTN(jconst_rgb_ycc_convert_mmx)
41
42EXTN(jconst_rgb_ycc_convert_mmx):
43
44PW_F0299_F0337 times 2 dw F_0_299, F_0_337
45PW_F0114_F0250 times 2 dw F_0_114, F_0_250
46PW_MF016_MF033 times 2 dw -F_0_168,-F_0_331
47PW_MF008_MF041 times 2 dw -F_0_081,-F_0_418
48PD_ONEHALFM1_CJ times 2 dd (1 << (SCALEBITS-1)) - 1 + (CENTERJSAMPLE << SCALEBITS)
49PD_ONEHALF times 2 dd (1 << (SCALEBITS-1))
50
51 alignz 16
52
53; --------------------------------------------------------------------------
54 SECTION SEG_TEXT
55 BITS 32
56;
57; Convert some rows of samples to the output colorspace.
58;
59; GLOBAL(void)
60; jsimd_rgb_ycc_convert_mmx (JDIMENSION img_width,
61; JSAMPARRAY input_buf, JSAMPIMAGE output_buf,
62; JDIMENSION output_row, int num_rows);
63;
64
65%define img_width(b) (b)+8 ; JDIMENSION img_width
66%define input_buf(b) (b)+12 ; JSAMPARRAY input_buf
67%define output_buf(b) (b)+16 ; JSAMPIMAGE output_buf
68%define output_row(b) (b)+20 ; JDIMENSION output_row
69%define num_rows(b) (b)+24 ; int num_rows
70
71%define original_ebp ebp+0
72%define wk(i) ebp-(WK_NUM-(i))*SIZEOF_MMWORD ; mmword wk[WK_NUM]
73%define WK_NUM 8
74%define gotptr wk(0)-SIZEOF_POINTER ; void * gotptr
75
76 align 16
77 global EXTN(jsimd_rgb_ycc_convert_mmx)
78
79EXTN(jsimd_rgb_ycc_convert_mmx):
80 push ebp
81 mov eax,esp ; eax = original ebp
82 sub esp, byte 4
83 and esp, byte (-SIZEOF_MMWORD) ; align to 64 bits
84 mov [esp],eax
85 mov ebp,esp ; ebp = aligned ebp
86 lea esp, [wk(0)]
87 pushpic eax ; make a room for GOT address
88 push ebx
89; push ecx ; need not be preserved
90; push edx ; need not be preserved
91 push esi
92 push edi
93
94 get_GOT ebx ; get GOT address
95 movpic POINTER [gotptr], ebx ; save GOT address
96
97 mov ecx, JDIMENSION [img_width(eax)] ; num_cols
98 test ecx,ecx
99 jz near .return
100
101 push ecx
102
103 mov esi, JSAMPIMAGE [output_buf(eax)]
104 mov ecx, JDIMENSION [output_row(eax)]
105 mov edi, JSAMPARRAY [esi+0*SIZEOF_JSAMPARRAY]
106 mov ebx, JSAMPARRAY [esi+1*SIZEOF_JSAMPARRAY]
107 mov edx, JSAMPARRAY [esi+2*SIZEOF_JSAMPARRAY]
108 lea edi, [edi+ecx*SIZEOF_JSAMPROW]
109 lea ebx, [ebx+ecx*SIZEOF_JSAMPROW]
110 lea edx, [edx+ecx*SIZEOF_JSAMPROW]
111
112 pop ecx
113
114 mov esi, JSAMPARRAY [input_buf(eax)]
115 mov eax, INT [num_rows(eax)]
116 test eax,eax
117 jle near .return
118 alignx 16,7
119.rowloop:
120 pushpic eax
121 push edx
122 push ebx
123 push edi
124 push esi
125 push ecx ; col
126
127 mov esi, JSAMPROW [esi] ; inptr
128 mov edi, JSAMPROW [edi] ; outptr0
129 mov ebx, JSAMPROW [ebx] ; outptr1
130 mov edx, JSAMPROW [edx] ; outptr2
131 movpic eax, POINTER [gotptr] ; load GOT address (eax)
132
133 cmp ecx, byte SIZEOF_MMWORD
134 jae short .columnloop
135 alignx 16,7
136
137%if RGB_PIXELSIZE == 3 ; ---------------
138
139.column_ld1:
140 push eax
141 push edx
142 lea ecx,[ecx+ecx*2] ; imul ecx,RGB_PIXELSIZE
143 test cl, SIZEOF_BYTE
144 jz short .column_ld2
145 sub ecx, byte SIZEOF_BYTE
146 xor eax,eax
147 mov al, BYTE [esi+ecx]
148.column_ld2:
149 test cl, SIZEOF_WORD
150 jz short .column_ld4
151 sub ecx, byte SIZEOF_WORD
152 xor edx,edx
153 mov dx, WORD [esi+ecx]
154 shl eax, WORD_BIT
155 or eax,edx
156.column_ld4:
157 movd mmA,eax
158 pop edx
159 pop eax
160 test cl, SIZEOF_DWORD
161 jz short .column_ld8
162 sub ecx, byte SIZEOF_DWORD
163 movd mmG, DWORD [esi+ecx]
164 psllq mmA, DWORD_BIT
165 por mmA,mmG
166.column_ld8:
167 test cl, SIZEOF_MMWORD
168 jz short .column_ld16
169 movq mmG,mmA
170 movq mmA, MMWORD [esi+0*SIZEOF_MMWORD]
171 mov ecx, SIZEOF_MMWORD
172 jmp short .rgb_ycc_cnv
173.column_ld16:
174 test cl, 2*SIZEOF_MMWORD
175 mov ecx, SIZEOF_MMWORD
176 jz short .rgb_ycc_cnv
177 movq mmF,mmA
178 movq mmA, MMWORD [esi+0*SIZEOF_MMWORD]
179 movq mmG, MMWORD [esi+1*SIZEOF_MMWORD]
180 jmp short .rgb_ycc_cnv
181 alignx 16,7
182
183.columnloop:
184 movq mmA, MMWORD [esi+0*SIZEOF_MMWORD]
185 movq mmG, MMWORD [esi+1*SIZEOF_MMWORD]
186 movq mmF, MMWORD [esi+2*SIZEOF_MMWORD]
187
188.rgb_ycc_cnv:
189 ; mmA=(00 10 20 01 11 21 02 12)
190 ; mmG=(22 03 13 23 04 14 24 05)
191 ; mmF=(15 25 06 16 26 07 17 27)
192
193 movq mmD,mmA
194 psllq mmA,4*BYTE_BIT ; mmA=(-- -- -- -- 00 10 20 01)
195 psrlq mmD,4*BYTE_BIT ; mmD=(11 21 02 12 -- -- -- --)
196
197 punpckhbw mmA,mmG ; mmA=(00 04 10 14 20 24 01 05)
198 psllq mmG,4*BYTE_BIT ; mmG=(-- -- -- -- 22 03 13 23)
199
200 punpcklbw mmD,mmF ; mmD=(11 15 21 25 02 06 12 16)
201 punpckhbw mmG,mmF ; mmG=(22 26 03 07 13 17 23 27)
202
203 movq mmE,mmA
204 psllq mmA,4*BYTE_BIT ; mmA=(-- -- -- -- 00 04 10 14)
205 psrlq mmE,4*BYTE_BIT ; mmE=(20 24 01 05 -- -- -- --)
206
207 punpckhbw mmA,mmD ; mmA=(00 02 04 06 10 12 14 16)
208 psllq mmD,4*BYTE_BIT ; mmD=(-- -- -- -- 11 15 21 25)
209
210 punpcklbw mmE,mmG ; mmE=(20 22 24 26 01 03 05 07)
211 punpckhbw mmD,mmG ; mmD=(11 13 15 17 21 23 25 27)
212
213 pxor mmH,mmH
214
215 movq mmC,mmA
216 punpcklbw mmA,mmH ; mmA=(00 02 04 06)
217 punpckhbw mmC,mmH ; mmC=(10 12 14 16)
218
219 movq mmB,mmE
220 punpcklbw mmE,mmH ; mmE=(20 22 24 26)
221 punpckhbw mmB,mmH ; mmB=(01 03 05 07)
222
223 movq mmF,mmD
224 punpcklbw mmD,mmH ; mmD=(11 13 15 17)
225 punpckhbw mmF,mmH ; mmF=(21 23 25 27)
226
227%else ; RGB_PIXELSIZE == 4 ; -----------
228
229.column_ld1:
230 test cl, SIZEOF_MMWORD/8
231 jz short .column_ld2
232 sub ecx, byte SIZEOF_MMWORD/8
233 movd mmA, DWORD [esi+ecx*RGB_PIXELSIZE]
234.column_ld2:
235 test cl, SIZEOF_MMWORD/4
236 jz short .column_ld4
237 sub ecx, byte SIZEOF_MMWORD/4
238 movq mmF,mmA
239 movq mmA, MMWORD [esi+ecx*RGB_PIXELSIZE]
240.column_ld4:
241 test cl, SIZEOF_MMWORD/2
242 mov ecx, SIZEOF_MMWORD
243 jz short .rgb_ycc_cnv
244 movq mmD,mmA
245 movq mmC,mmF
246 movq mmA, MMWORD [esi+0*SIZEOF_MMWORD]
247 movq mmF, MMWORD [esi+1*SIZEOF_MMWORD]
248 jmp short .rgb_ycc_cnv
249 alignx 16,7
250
251.columnloop:
252 movq mmA, MMWORD [esi+0*SIZEOF_MMWORD]
253 movq mmF, MMWORD [esi+1*SIZEOF_MMWORD]
254 movq mmD, MMWORD [esi+2*SIZEOF_MMWORD]
255 movq mmC, MMWORD [esi+3*SIZEOF_MMWORD]
256
257.rgb_ycc_cnv:
258 ; mmA=(00 10 20 30 01 11 21 31)
259 ; mmF=(02 12 22 32 03 13 23 33)
260 ; mmD=(04 14 24 34 05 15 25 35)
261 ; mmC=(06 16 26 36 07 17 27 37)
262
263 movq mmB,mmA
264 punpcklbw mmA,mmF ; mmA=(00 02 10 12 20 22 30 32)
265 punpckhbw mmB,mmF ; mmB=(01 03 11 13 21 23 31 33)
266
267 movq mmG,mmD
268 punpcklbw mmD,mmC ; mmD=(04 06 14 16 24 26 34 36)
269 punpckhbw mmG,mmC ; mmG=(05 07 15 17 25 27 35 37)
270
271 movq mmE,mmA
272 punpcklwd mmA,mmD ; mmA=(00 02 04 06 10 12 14 16)
273 punpckhwd mmE,mmD ; mmE=(20 22 24 26 30 32 34 36)
274
275 movq mmH,mmB
276 punpcklwd mmB,mmG ; mmB=(01 03 05 07 11 13 15 17)
277 punpckhwd mmH,mmG ; mmH=(21 23 25 27 31 33 35 37)
278
279 pxor mmF,mmF
280
281 movq mmC,mmA
282 punpcklbw mmA,mmF ; mmA=(00 02 04 06)
283 punpckhbw mmC,mmF ; mmC=(10 12 14 16)
284
285 movq mmD,mmB
286 punpcklbw mmB,mmF ; mmB=(01 03 05 07)
287 punpckhbw mmD,mmF ; mmD=(11 13 15 17)
288
289 movq mmG,mmE
290 punpcklbw mmE,mmF ; mmE=(20 22 24 26)
291 punpckhbw mmG,mmF ; mmG=(30 32 34 36)
292
293 punpcklbw mmF,mmH
294 punpckhbw mmH,mmH
295 psrlw mmF,BYTE_BIT ; mmF=(21 23 25 27)
296 psrlw mmH,BYTE_BIT ; mmH=(31 33 35 37)
297
298%endif ; RGB_PIXELSIZE ; ---------------
299
300 ; mm0=(R0 R2 R4 R6)=RE, mm2=(G0 G2 G4 G6)=GE, mm4=(B0 B2 B4 B6)=BE
301 ; mm1=(R1 R3 R5 R7)=RO, mm3=(G1 G3 G5 G7)=GO, mm5=(B1 B3 B5 B7)=BO
302
303 ; (Original)
304 ; Y = 0.29900 * R + 0.58700 * G + 0.11400 * B
305 ; Cb = -0.16874 * R - 0.33126 * G + 0.50000 * B + CENTERJSAMPLE
306 ; Cr = 0.50000 * R - 0.41869 * G - 0.08131 * B + CENTERJSAMPLE
307 ;
308 ; (This implementation)
309 ; Y = 0.29900 * R + 0.33700 * G + 0.11400 * B + 0.25000 * G
310 ; Cb = -0.16874 * R - 0.33126 * G + 0.50000 * B + CENTERJSAMPLE
311 ; Cr = 0.50000 * R - 0.41869 * G - 0.08131 * B + CENTERJSAMPLE
312
313 movq MMWORD [wk(0)], mm0 ; wk(0)=RE
314 movq MMWORD [wk(1)], mm1 ; wk(1)=RO
315 movq MMWORD [wk(2)], mm4 ; wk(2)=BE
316 movq MMWORD [wk(3)], mm5 ; wk(3)=BO
317
318 movq mm6,mm1
319 punpcklwd mm1,mm3
320 punpckhwd mm6,mm3
321 movq mm7,mm1
322 movq mm4,mm6
323 pmaddwd mm1,[GOTOFF(eax,PW_F0299_F0337)] ; mm1=ROL*FIX(0.299)+GOL*FIX(0.337)
324 pmaddwd mm6,[GOTOFF(eax,PW_F0299_F0337)] ; mm6=ROH*FIX(0.299)+GOH*FIX(0.337)
325 pmaddwd mm7,[GOTOFF(eax,PW_MF016_MF033)] ; mm7=ROL*-FIX(0.168)+GOL*-FIX(0.331)
326 pmaddwd mm4,[GOTOFF(eax,PW_MF016_MF033)] ; mm4=ROH*-FIX(0.168)+GOH*-FIX(0.331)
327
328 movq MMWORD [wk(4)], mm1 ; wk(4)=ROL*FIX(0.299)+GOL*FIX(0.337)
329 movq MMWORD [wk(5)], mm6 ; wk(5)=ROH*FIX(0.299)+GOH*FIX(0.337)
330
331 pxor mm1,mm1
332 pxor mm6,mm6
333 punpcklwd mm1,mm5 ; mm1=BOL
334 punpckhwd mm6,mm5 ; mm6=BOH
335 psrld mm1,1 ; mm1=BOL*FIX(0.500)
336 psrld mm6,1 ; mm6=BOH*FIX(0.500)
337
338 movq mm5,[GOTOFF(eax,PD_ONEHALFM1_CJ)] ; mm5=[PD_ONEHALFM1_CJ]
339
340 paddd mm7,mm1
341 paddd mm4,mm6
342 paddd mm7,mm5
343 paddd mm4,mm5
344 psrld mm7,SCALEBITS ; mm7=CbOL
345 psrld mm4,SCALEBITS ; mm4=CbOH
346 packssdw mm7,mm4 ; mm7=CbO
347
348 movq mm1, MMWORD [wk(2)] ; mm1=BE
349
350 movq mm6,mm0
351 punpcklwd mm0,mm2
352 punpckhwd mm6,mm2
353 movq mm5,mm0
354 movq mm4,mm6
355 pmaddwd mm0,[GOTOFF(eax,PW_F0299_F0337)] ; mm0=REL*FIX(0.299)+GEL*FIX(0.337)
356 pmaddwd mm6,[GOTOFF(eax,PW_F0299_F0337)] ; mm6=REH*FIX(0.299)+GEH*FIX(0.337)
357 pmaddwd mm5,[GOTOFF(eax,PW_MF016_MF033)] ; mm5=REL*-FIX(0.168)+GEL*-FIX(0.331)
358 pmaddwd mm4,[GOTOFF(eax,PW_MF016_MF033)] ; mm4=REH*-FIX(0.168)+GEH*-FIX(0.331)
359
360 movq MMWORD [wk(6)], mm0 ; wk(6)=REL*FIX(0.299)+GEL*FIX(0.337)
361 movq MMWORD [wk(7)], mm6 ; wk(7)=REH*FIX(0.299)+GEH*FIX(0.337)
362
363 pxor mm0,mm0
364 pxor mm6,mm6
365 punpcklwd mm0,mm1 ; mm0=BEL
366 punpckhwd mm6,mm1 ; mm6=BEH
367 psrld mm0,1 ; mm0=BEL*FIX(0.500)
368 psrld mm6,1 ; mm6=BEH*FIX(0.500)
369
370 movq mm1,[GOTOFF(eax,PD_ONEHALFM1_CJ)] ; mm1=[PD_ONEHALFM1_CJ]
371
372 paddd mm5,mm0
373 paddd mm4,mm6
374 paddd mm5,mm1
375 paddd mm4,mm1
376 psrld mm5,SCALEBITS ; mm5=CbEL
377 psrld mm4,SCALEBITS ; mm4=CbEH
378 packssdw mm5,mm4 ; mm5=CbE
379
380 psllw mm7,BYTE_BIT
381 por mm5,mm7 ; mm5=Cb
382 movq MMWORD [ebx], mm5 ; Save Cb
383
384 movq mm0, MMWORD [wk(3)] ; mm0=BO
385 movq mm6, MMWORD [wk(2)] ; mm6=BE
386 movq mm1, MMWORD [wk(1)] ; mm1=RO
387
388 movq mm4,mm0
389 punpcklwd mm0,mm3
390 punpckhwd mm4,mm3
391 movq mm7,mm0
392 movq mm5,mm4
393 pmaddwd mm0,[GOTOFF(eax,PW_F0114_F0250)] ; mm0=BOL*FIX(0.114)+GOL*FIX(0.250)
394 pmaddwd mm4,[GOTOFF(eax,PW_F0114_F0250)] ; mm4=BOH*FIX(0.114)+GOH*FIX(0.250)
395 pmaddwd mm7,[GOTOFF(eax,PW_MF008_MF041)] ; mm7=BOL*-FIX(0.081)+GOL*-FIX(0.418)
396 pmaddwd mm5,[GOTOFF(eax,PW_MF008_MF041)] ; mm5=BOH*-FIX(0.081)+GOH*-FIX(0.418)
397
398 movq mm3,[GOTOFF(eax,PD_ONEHALF)] ; mm3=[PD_ONEHALF]
399
400 paddd mm0, MMWORD [wk(4)]
401 paddd mm4, MMWORD [wk(5)]
402 paddd mm0,mm3
403 paddd mm4,mm3
404 psrld mm0,SCALEBITS ; mm0=YOL
405 psrld mm4,SCALEBITS ; mm4=YOH
406 packssdw mm0,mm4 ; mm0=YO
407
408 pxor mm3,mm3
409 pxor mm4,mm4
410 punpcklwd mm3,mm1 ; mm3=ROL
411 punpckhwd mm4,mm1 ; mm4=ROH
412 psrld mm3,1 ; mm3=ROL*FIX(0.500)
413 psrld mm4,1 ; mm4=ROH*FIX(0.500)
414
415 movq mm1,[GOTOFF(eax,PD_ONEHALFM1_CJ)] ; mm1=[PD_ONEHALFM1_CJ]
416
417 paddd mm7,mm3
418 paddd mm5,mm4
419 paddd mm7,mm1
420 paddd mm5,mm1
421 psrld mm7,SCALEBITS ; mm7=CrOL
422 psrld mm5,SCALEBITS ; mm5=CrOH
423 packssdw mm7,mm5 ; mm7=CrO
424
425 movq mm3, MMWORD [wk(0)] ; mm3=RE
426
427 movq mm4,mm6
428 punpcklwd mm6,mm2
429 punpckhwd mm4,mm2
430 movq mm1,mm6
431 movq mm5,mm4
432 pmaddwd mm6,[GOTOFF(eax,PW_F0114_F0250)] ; mm6=BEL*FIX(0.114)+GEL*FIX(0.250)
433 pmaddwd mm4,[GOTOFF(eax,PW_F0114_F0250)] ; mm4=BEH*FIX(0.114)+GEH*FIX(0.250)
434 pmaddwd mm1,[GOTOFF(eax,PW_MF008_MF041)] ; mm1=BEL*-FIX(0.081)+GEL*-FIX(0.418)
435 pmaddwd mm5,[GOTOFF(eax,PW_MF008_MF041)] ; mm5=BEH*-FIX(0.081)+GEH*-FIX(0.418)
436
437 movq mm2,[GOTOFF(eax,PD_ONEHALF)] ; mm2=[PD_ONEHALF]
438
439 paddd mm6, MMWORD [wk(6)]
440 paddd mm4, MMWORD [wk(7)]
441 paddd mm6,mm2
442 paddd mm4,mm2
443 psrld mm6,SCALEBITS ; mm6=YEL
444 psrld mm4,SCALEBITS ; mm4=YEH
445 packssdw mm6,mm4 ; mm6=YE
446
447 psllw mm0,BYTE_BIT
448 por mm6,mm0 ; mm6=Y
449 movq MMWORD [edi], mm6 ; Save Y
450
451 pxor mm2,mm2
452 pxor mm4,mm4
453 punpcklwd mm2,mm3 ; mm2=REL
454 punpckhwd mm4,mm3 ; mm4=REH
455 psrld mm2,1 ; mm2=REL*FIX(0.500)
456 psrld mm4,1 ; mm4=REH*FIX(0.500)
457
458 movq mm0,[GOTOFF(eax,PD_ONEHALFM1_CJ)] ; mm0=[PD_ONEHALFM1_CJ]
459
460 paddd mm1,mm2
461 paddd mm5,mm4
462 paddd mm1,mm0
463 paddd mm5,mm0
464 psrld mm1,SCALEBITS ; mm1=CrEL
465 psrld mm5,SCALEBITS ; mm5=CrEH
466 packssdw mm1,mm5 ; mm1=CrE
467
468 psllw mm7,BYTE_BIT
469 por mm1,mm7 ; mm1=Cr
470 movq MMWORD [edx], mm1 ; Save Cr
471
472 sub ecx, byte SIZEOF_MMWORD
473 add esi, byte RGB_PIXELSIZE*SIZEOF_MMWORD ; inptr
474 add edi, byte SIZEOF_MMWORD ; outptr0
475 add ebx, byte SIZEOF_MMWORD ; outptr1
476 add edx, byte SIZEOF_MMWORD ; outptr2
477 cmp ecx, byte SIZEOF_MMWORD
478 jae near .columnloop
479 test ecx,ecx
480 jnz near .column_ld1
481
482 pop ecx ; col
483 pop esi
484 pop edi
485 pop ebx
486 pop edx
487 poppic eax
488
489 add esi, byte SIZEOF_JSAMPROW ; input_buf
490 add edi, byte SIZEOF_JSAMPROW
491 add ebx, byte SIZEOF_JSAMPROW
492 add edx, byte SIZEOF_JSAMPROW
493 dec eax ; num_rows
494 jg near .rowloop
495
496 emms ; empty MMX state
497
498.return:
499 pop edi
500 pop esi
501; pop edx ; need not be preserved
502; pop ecx ; need not be preserved
503 pop ebx
504 mov esp,ebp ; esp <- aligned ebp
505 pop esp ; esp <- original ebp
506 pop ebp
507 ret
508