diff --git a/runtime/ftplugin/basic.vim b/runtime/ftplugin/basic.vim
index c6ec254..a8f6b08 100644
--- a/runtime/ftplugin/basic.vim
+++ b/runtime/ftplugin/basic.vim
@@ -1,7 +1,7 @@
 " Vim filetype plugin file
-" Language:	BASIC
+" Language:	BASIC (QuickBASIC 4.5)
 " Maintainer:	Doug Kearns <dougkearns@gmail.com>
-" Last Change:	2015 Jan 10
+" Last Change:	2021 Mar 16
 
 if exists("b:did_ftplugin")
   finish
@@ -11,17 +11,46 @@
 let s:cpo_save = &cpo
 set cpo&vim
 
-setlocal comments=:REM,:'
+setlocal comments=:REM\ ,:Rem\ ,:rem\ ,:'
 setlocal commentstring='\ %s
 setlocal formatoptions-=t formatoptions+=croql
 
-if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
-  let b:browsefilter = "BASIC Source Files (*.bas)\t*.bas\n" .
-		     \ "All Files (*.*)\t*.*\n"
+" TODO: support exit ... as middle matches?
+if exists("loaded_matchit") && !exists("b:match_words")
+  let s:line_start	= '\%(^\s*\)\@<='
+  let s:not_end		= '\%(end\s\+\)\@<!'
+  let s:not_end_or_exit	= '\%(\%(end\|exit\)\s\+\)\@<!'
+
+  let b:match_ignorecase = 1
+  let b:match_words =
+		\     s:not_end_or_exit .. '\<def\s\+fn:\<end\s\+def\>,' ..
+		\     s:not_end_or_exit .. '\<function\>:\<end\s\+function\>,' ..
+		\     s:not_end_or_exit .. '\<sub\>:\<end\s\+sub\>,' ..
+		\     s:not_end .. '\<type\>:\<end\s\+type\>,' ..
+		\     s:not_end .. '\<select\>:\%(select\s\+\)\@<!\<case\%(\s\+\%(else\|is\)\)\=\>:\<end\s\+select\>,' ..
+		\     '\<do\>:\<loop\>,' ..
+		\     '\<for\>\%(\s\+\%(input\|output\|random\|append\|binary\)\)\@!:\<next\>,' ..
+		\     '\<while\>:\<wend\>,' ..
+		\     s:line_start .. 'if\%(.*\<then\s*\%($\|''\)\)\@=:\<\%(' .. s:line_start .. 'else\|elseif\)\>:\<end\s\+if\>,' ..
+		\     '\<lock\>:\<unlock\>'
+
+  let b:match_skip = 'synIDattr(synID(line("."),col("."),1),"name") =~? "comment\\|string" || ' ..
+		\    'strpart(getline("."), 0, col(".") ) =~? "\\<exit\\s\\+"'
+
+  unlet s:line_start s:not_end s:not_end_or_exit
 endif
 
-let b:undo_ftplugin = "setl fo< com< cms< sua<" .
-		    \ " | unlet! b:browsefilter"
+if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
+  let b:browsefilter = "BASIC Source Files (*.bas)\t*.bas\n" ..
+		\      "BASIC Include Files (*.bi, *.bm)\t*.bi;*.bm\n" ..
+		\      "All Files (*.*)\t*.*\n"
+endif
+
+let b:undo_ftplugin = "setl fo< com< cms<" ..
+		\     " | unlet! b:match_ignorecase b:match_skip b:match_words" ..
+		\     " | unlet! b:browsefilter"
 
 let &cpo = s:cpo_save
 unlet s:cpo_save
+
+" vim: nowrap sw=2 sts=2 ts=8 noet fdm=marker:
diff --git a/runtime/ftplugin/freebasic.vim b/runtime/ftplugin/freebasic.vim
index a2bb459..58c2b4c 100644
--- a/runtime/ftplugin/freebasic.vim
+++ b/runtime/ftplugin/freebasic.vim
@@ -1,13 +1,65 @@
 " Vim filetype plugin file
-" Language:	FreeBasic
+" Language:	FreeBASIC
 " Maintainer:	Doug Kearns <dougkearns@gmail.com>
-" Last Change:	2015 Jan 10
+" Last Change:	2021 Mar 16
 
+" Setup {{{1
 if exists("b:did_ftplugin")
   finish
 endif
-let b:did_ftplugin = 1
+
+let s:cpo_save = &cpo
+set cpo&vim
 
 runtime! ftplugin/basic.vim
 
-" vim: ts=8
+let s:dialect = freebasic#GetDialect()
+
+" Comments {{{1
+" add ''comments before 'comments
+let &l:comments = "sO:*\ -,mO:*\ \ ,exO:*/,s1:/',mb:',ex:'/,:''," .. &l:comments
+
+" Match words {{{1
+if exists("loaded_matchit")
+  let s:not_end = '\%(end\s\+\)\@<!'
+
+  let b:match_words ..= ','
+
+  if s:dialect == 'fb'
+    let b:match_words ..= s:not_end .. '\<constructor\>:\<end\s\+constructor\>,' ..
+		  \	  s:not_end .. '\<destructor\>:\<end\s\+destructor\>,' ..
+		  \	  s:not_end .. '\<property\>:\<end\s\+property\>,' ..
+		  \	  s:not_end .. '\<operator\>:\<end\s\+operator\>,' ..
+		  \	  s:not_end .. '\<extern\%(\s\+"\)\@=:\<end\s\+extern\>,'
+  endif
+
+  if s:dialect == 'fb' || s:dialect == 'deprecated'
+    let b:match_words ..= s:not_end .. '\<scope\>:\<end\s\+scope\>,'
+  endif
+
+  if s:dialect == 'qb'
+    let b:match_words ..= s:not_end .. '\<__asm\>:\<end\s\+__asm\>,' ..
+		  \	  s:not_end .. '\<__union\>:\<end\s\+__union\>,' ..
+		  \	  s:not_end .. '\<__with\>:\<end\s\+__with\>,'
+  else
+    let b:match_words ..= s:not_end .. '\<asm\>:\<end\s\+asm\>,' ..
+		  \	  s:not_end .. '\<namespace\>:\<end\s\+namespace\>,' ..
+		  \	  s:not_end .. '\<union\>:\<end\s\+union\>,' ..
+		  \	  s:not_end .. '\<with\>:\<end\s\+with\>,'
+  endif
+
+  let b:match_words ..= s:not_end .. '\<enum\>:\<end\s\+enum\>,' ..
+		  \	'^#\s*\%(if\|ifdef\|ifndef\)\>:^#\s*\%(else\|elseif\)\>:^#\s*endif\>,' ..
+		  \	'^#\s*macro\>:^#\s*endmacro\>'
+
+  " skip "function = <retval>"
+  let b:match_skip ..= '|| strpart(getline("."), col(".") - 1) =~? "^\\<function\\s\\+="'
+
+  unlet s:not_end
+endif
+
+" Cleanup {{{1
+let &cpo = s:cpo_save
+unlet s:cpo_save
+
+" vim: nowrap sw=2 sts=2 ts=8 noet fdm=marker:
diff --git a/runtime/ftplugin/qb64.vim b/runtime/ftplugin/qb64.vim
new file mode 100644
index 0000000..0fa36fc
--- /dev/null
+++ b/runtime/ftplugin/qb64.vim
@@ -0,0 +1,26 @@
+" Vim filetype plugin file
+" Language:	QB64
+" Maintainer:	Doug Kearns <dougkearns@gmail.com>
+
+if exists("b:did_ftplugin")
+  finish
+endif
+
+let s:cpo_save = &cpo
+set cpo&vim
+
+runtime! ftplugin/basic.vim
+
+let s:not_end = '\%(end\s\+\)\@<!'
+
+let b:match_words ..= ',' ..
+		\     s:not_end .. '\<declare\>:\<end\s\+declare\>,' ..
+		\     '\<select\s\+everycase\>:\%(select\s\+\)\@<!\<case\%(\s\+\%(else\|is\)\)\=\>:\<end\s\+select\>,' ..
+		\     '$IF\>:$\%(ELSEIF\|ELSE\)\>:$END\s*IF\>'
+
+unlet s:not_end
+
+let &cpo = s:cpo_save
+unlet s:cpo_save
+
+" vim: nowrap sw=2 sts=2 ts=8 noet fdm=marker: